Cara Menghitung Usia dengan Excel Beserta Rumus dan Contoh

Cara menghitung usia dengan Excel Otomatis - Tutorial menunjukkan berbagai cara untuk mendapatkan usia sejak lahir di Excel. Anda akan belajar beberapa rumus untuk menghitung usia sebagai jumlah tahun lengkap, dapatkan usia tepat dalam tahun, bulan, dan hari pada tanggal hari ini atau tanggal tertentu.

Tidak ada fungsi khusus untuk menghitung usia di Excel, namun ada beberapa cara berbeda untuk mengonversi tanggal lahir ke usia.

Tutorial ini akan menjelaskan kelebihan dan kekurangan dari masing-masing cara, menunjukkan cara membuat formula perhitungan usia yang sempurna di Excel dan menyesuaikannya untuk menyelesaikan beberapa tugas tertentu.

Yuk, belajar bersama dengan menyimak artikel kali ini yaitu cara mudah menghitung usia dengan excel otomatis dibawah ini !


Cara menghitung usia sejak tanggal lahir di Excel


cara menghitung usia dengan excel beserta rumus dan contoh

Dalam kehidupan sehari-hari, pertanyaan " Berapa usia Anda? " Biasanya menyiratkan jawaban yang menunjukkan berapa tahun Anda telah hidup. Di Microsoft Excel, Anda bisa membuat rumus untuk menghitung usia tepat dalam bulan, hari, jam, dan bahkan menit. Tapi mari kita menjadi tradisional, dan belajar bagaimana menghitung usia dari DOB di tahun-tahun pertama.

Rumus Excel dasar untuk usia dalam bertahun-tahun


Bagaimana Anda biasanya mengetahui usia seseorang? Cukup dengan mengurangi tanggal lahir dari tanggal saat ini. Formula umur konvensional ini juga bisa digunakan di Excel.

Dengan asumsi tanggal lahir ada di sel B2, rumus untuk menghitung usia dalam tahun adalah sebagai berikut:


=(TODAY()-B2)/365


Bagian pertama dari rumus (HARI INI () - B2) mengembalikan perbedaan antara tanggal saat ini dan tanggal lahir adalah hari, dan kemudian Anda membagi angka itu dengan 365 untuk mendapatkan angka tahun.

Rumusnya jelas dan mudah diingat, namun, ada masalah kecil. Dalam kebanyakan kasus, ini mengembalikan angka desimal seperti yang ditunjukkan pada tangkapan layar di bawah ini.


Untuk menampilkan jumlah tahun lengkap, gunakan fungsi INT untuk membulatkan desimal ke bilangan bulat terdekat:

=INT((TODAY()-B2)/365)


Kekurangan:  Menggunakan rumus usia ini di Excel menghasilkan hasil yang cukup akurat, tetapi tidak sempurna. Membagi berdasarkan jumlah hari rata-rata dalam setahun berfungsi dengan baik sebagian besar waktu, tetapi kadang-kadang usia salah. Misalnya, jika seseorang dilahirkan pada tanggal 29 Februari dan hari ini adalah tanggal 28 Februari, rumusnya akan membuat seseorang satu hari lebih tua.

Sebagai alternatif, Anda dapat membagi dengan 365,25 bukannya 365 karena setiap tahun keempat memiliki 366 hari. Namun, pendekatan ini juga tidak sempurna. Misalnya, jika Anda menghitung usia anak yang belum melewati tahun kabisat, membagi dengan 365,25 menghasilkan hasil yang salah.

Secara keseluruhan, mengurangi tanggal lahir dari tanggal saat ini berfungsi dengan baik dalam kehidupan normal, tetapi bukan pendekatan yang ideal di Excel. Selanjutnya dalam tutorial ini, Anda akan belajar beberapa fungsi khusus yang menghitung usia tanpa cacat terlepas dari tahun.

Hitung usia sejak tanggal lahir dengan fungsi YEARFRAC


Cara yang lebih dapat diandalkan untuk mengonversi DOB ke usia di Excel adalah menggunakan fungsi YEARFRAC yang mengembalikan pecahan tahun, yaitu jumlah hari penuh antara dua tanggal.

Sintaks fungsi YEARFRAC adalah sebagai berikut:

YEARFRAC (start_date, end_date, [basis])

Dua argumen pertama jelas dan hampir tidak memerlukan penjelasan tambahan. Basis adalah argumen opsional yang menentukan basis hitungan hari untuk digunakan.

Untuk membuat formula usia yang benar-benar benar, berikan nilai-nilai berikut ke fungsi YEARFRAC:


  • Start_date - tanggal lahir.
  • End_date - TODAY () berfungsi untuk mengembalikan tanggal hari ini.
  • Dasar - gunakan basis 1 yang memberi tahu Excel untuk membagi jumlah hari aktual per bulan dengan jumlah hari aktual per tahun.


Mempertimbangkan hal di atas, rumus Excel untuk menghitung usia sejak tanggal lahir adalah sebagai berikut:

YEARFRAC ( tanggal lahir , HARI INI (), 1)

Dengan asumsi tanggal lahir ada di sel B2, rumusnya berbentuk seperti berikut:

=YEARFRAC(B2, TODAY(), 1)


Seperti pada contoh sebelumnya, hasil dari fungsi YEARFRAC juga angka desimal. Untuk memperbaikinya, gunakan ROUNDDOWN fungsi dengan 0 pada argumen terakhir karena Anda tidak ingin ada tempat desimal.

Jadi, inilah rumus YEARFRAC yang ditingkatkan untuk menghitung usia di Excel:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)


Hitung usia di Excel dengan DATEDIF


Satu lagi cara untuk mengonversi tanggal lahir ke usia di Excel adalah menggunakan fungsi DATEDIF :

DATEDIF (start_date, end_date, unit)

Fungsi ini dapat mengembalikan perbedaan antara dua tanggal dalam berbagai unit waktu seperti tahun, bulan dan hari, tergantung pada nilai yang Anda berikan dalam argumen unit :


  • Y - mengembalikan jumlah tahun lengkap antara tanggal mulai dan tanggal berakhir.
  • M - mengembalikan jumlah bulan lengkap antara tanggal.
  • D - mengembalikan jumlah hari antara dua tanggal.
  • YM - mengembalikan bulan , mengabaikan hari dan tahun.
  • MD - mengembalikan perbedaan dalam hari , mengabaikan bulan dan tahun.
  • YD - mengembalikan perbedaan dalam hitungan hari , mengabaikan tahun.


Karena kami bermaksud menghitung usia dalam tahun , kami menggunakan unit "y":

DATEDIF ( tanggal lahir , HARI INI (), "y")

Dalam contoh ini, DOB ada di sel B2, dan Anda mereferensikan sel ini dalam rumus usia Anda:

=DATEDIF(B2, TODAY(), "y")


Tidak diperlukan fungsi pembulatan tambahan dalam hal ini karena rumus DATEDIF dengan unit "y" menghitung jumlah tahun penuh:


Cara mendapatkan usia sejak ulang tahun dalam tahun, bulan, dan hari


Seperti yang baru saja Anda lihat, menghitung usia sebagai jumlah tahun penuh yang dijalani orang itu mudah, tetapi itu tidak selalu mencukupi. Jika Anda ingin mengetahui usia pastinya, yaitu berapa tahun, bulan, dan hari antara tanggal lahir seseorang dan tanggal saat ini, tulis 3 fungsi DATEIF yang berbeda:


  1. Untuk mendapatkan jumlah tahun: =DATEDIF(B2, TODAY(), "Y")
  2. Untuk mendapatkan jumlah bulan: =DATEDIF(B2, TODAY(), "YM")
  3. Untuk mendapatkan jumlah hari: =DATEDIF(B2,TODAY(),"MD")


Di mana B2 adalah tanggal lahir.

Dan kemudian, gabungkan fungsi-fungsi di atas dalam satu rumus, seperti ini:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

Rumus di atas mengembalikan 3 angka (tahun, bulan, dan hari) yang disatukan dalam string teks tunggal, seperti yang ditunjukkan pada tangkapan layar di bawah ini:


Tidak masuk akal, eh? Untuk membuat hasil lebih bermakna, pisahkan angka dengan koma dan tentukan apa artinya setiap nilai:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

Hasilnya terlihat jauh lebih baik sekarang:


Formula berfungsi dengan baik, tetapi Anda dapat memperbaikinya lebih jauh dengan menyembunyikan nilai nol. Untuk ini, tambahkan 3 pernyataan IF yang memeriksa 0, satu per setiap DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

Tangkapan layar berikut menunjukkan rumus akhir usia Excel dalam aksi - ini mengembalikan usia dalam tahun, bulan, dan hari, hanya menampilkan nilai - nilai yang tidak nol :


Tips. Jika Anda mencari rumus Excel untuk menghitung usia dalam tahun dan bulan , ambil rumus di atas dan hapus blok IF (DATEDIF ()) terakhir yang menghitung hari.

Rumus khusus untuk menghitung usia di Excel


Rumus perhitungan usia generik yang dibahas di atas berfungsi baik dalam kebanyakan kasus. Namun, dalam beberapa situasi, Anda mungkin memerlukan sesuatu yang sangat spesifik. Tentu saja, tidak mungkin untuk mencakup setiap dan setiap skenario, tetapi contoh-contoh berikut akan memberi Anda beberapa ide tentang bagaimana Anda dapat mengubah formula usia tergantung pada tugas khusus Anda.

Cara menghitung usia pada tanggal tertentu di Excel


Jika Anda ingin mengetahui usia seseorang pada tanggal tertentu, gunakan DATEDIF rumus usia yang dibahas di atas, tapi menggantikan fungsi TODAY () dalam 2 nd argumen dengan tanggal tertentu.

Dengan asumsi tanggal lahir dalam B1, rumus berikut akan kembali usia pada 1 Januari 2020:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

Untuk membuat rumus usia Anda lebih fleksibel, Anda dapat memasukkan tanggal di beberapa sel dan referensi sel itu di rumus Anda:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

Di mana B1 adalah DOB, dan B2 adalah tanggal di mana Anda ingin menghitung usia.


Hitung usia dalam tahun tertentu


Formula ini sangat berguna dalam situasi ketika tanggal lengkap untuk menghitung pada tidak ditentukan, dan Anda hanya tahu tahun.

Katakanlah Anda bekerja dengan database medis, dan tujuan Anda adalah untuk mengetahui usia pasien pada saat mereka menjalani pemeriksaan medis penuh terakhir.

Dengan asumsi tanggal lahir berada di kolom B dimulai dengan baris 3, dan tahun pemeriksaan medis terakhir adalah di kolom C, rumus perhitungan usia adalah sebagai berikut:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

Karena tanggal pasti pemeriksaan medis tidak ditentukan, Anda menggunakan fungsi DATE dengan argumen tanggal dan bulan sewenang-wenang, misalnya DATE (C3, 1, 1).

Fungsi DATE mengekstrak tahun dari sel B3, membuat tanggal lengkap menggunakan angka bulan dan hari yang Anda berikan (1-Jan dalam contoh ini), dan meneruskan tanggal itu ke DATEDIF. Hasilnya, Anda mendapatkan usia pasien pada 1 Januari tahun tertentu:


Cari tahu tanggal ketika seseorang mencapai usia N tahun


Andaikata teman Anda lahir pada 8 Maret 1978. Bagaimana Anda tahu tanggal berapa ia menyelesaikan usianya yang ke-50? Biasanya, Anda cukup menambahkan 50 tahun pada tanggal lahir orang tersebut. Di Excel, Anda melakukan hal yang sama menggunakan fungsi DATE:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

Di mana B2 adalah tanggal lahir.

Alih-alih mengkodekan jumlah tahun dalam rumus, Anda dapat mereferensikan sel tertentu tempat pengguna Anda dapat memasukkan jumlah tahun (F1 pada tangkapan layar di bawah):


Hitung usia dari hari, bulan, dan tahun dalam sel yang berbeda


Ketika tanggal lahir dibagi menjadi 3 sel yang berbeda (misalnya tahun dalam B3, bulan dalam C3 dan hari dalam D3), Anda dapat menghitung usia dengan cara ini:


  • Dapatkan tanggal lahir dengan menggunakan fungsi DATE dan DATEVALUE:
  • DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)
  • Cantumkan formula di atas ke dalam DATEDIF untuk menghitung usia sejak tanggal lahir dalam tahun, bulan, dan hari:

=DATEDIF(DATE(B3,MONTH(DATEVALUE(C3&"1")),D3),TODAY(),"y") & " Years, "& DATEDIF(DATE(B3,MONTH(DATEVALUE(C3&"1")),D3),TODAY(),"ym") & " Months, "&  DATEDIF(DATE(B3,MONTH(DATEVALUE(C3&"1")),D3),TODAY(),"md") & " Days"


Kalkulator usia di Excel


Jika Anda ingin memiliki kalkulator usia Anda sendiri di Excel, Anda bisa membuatnya dengan menggunakan beberapa rumus DATEIF yang berbeda yang dijelaskan di bawah ini. Jika Anda lebih suka tidak menemukan kembali roda, Anda dapat menggunakan kalkulator usia yang dibuat oleh para profesional Excel kami.

Cara membuat kalkulator usia di Excel


Sekarang setelah Anda tahu cara membuat rumus usia di Excel, Anda bisa membuat kalkulator usia khusus, misalnya yang ini:

misalnya yang ini:

Apa yang Anda lihat di atas adalah lembar Excel Online yang disematkan, jadi silakan masukkan tanggal lahir Anda di sel yang sesuai, dan usia Anda akan segera bertambah.

Kalkulator menggunakan rumus berikut untuk menghitung usia berdasarkan tanggal lahir dalam sel A3 dan tanggal hari ini.


  • Formula dalam B5 menghitung usia dalam tahun, bulan, dan hari:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"


  • Formula dalam B6 menghitung usia dalam bulan:

=DATEDIF($B$3,TODAY(),"m")


  • Formula dalam B7 menghitung usia dalam hari:

=DATEDIF($B$3,TODAY(),"d")

Jika Anda memiliki pengalaman dengan kontrol Excel Form, Anda bisa menambahkan opsi untuk menghitung usia pada tanggal tertentu, seperti yang ditunjukkan pada tangkapan layar berikut:


Untuk ini, tambahkan beberapa tombol opsi ( tab Pengembang  >  Sisipkan  >  Kontrol formulir  >  Tombol Opsi ), dan tautkan ke beberapa sel. Dan kemudian, tulis rumus IF / DATEDIF untuk mendapatkan usia baik pada tanggal hari ini atau pada tanggal yang ditentukan oleh pengguna.

Rumusnya bekerja dengan logika berikut:


  • Jika   kotak opsi tanggal hari ini dipilih, nilai 1 muncul di sel tertaut (I5 dalam contoh ini), dan rumus usia menghitung berdasarkan tanggal hari ini:

IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")


  • Jika   tombol opsi tanggal spesifik dipilih DAN tanggal dimasukkan dalam sel B7, usia dihitung pada tanggal yang ditentukan:

IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))


  • Terakhir, buat sarang fungsi-fungsi di atas satu sama lain, dan Anda akan mendapatkan formula perhitungan usia lengkap (dalam B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

Rumus dalam B10 dan B11 bekerja dengan logika yang sama. Tentu saja, mereka jauh lebih sederhana karena mereka hanya menyertakan satu fungsi DATEIF untuk mengembalikan usia sebagai jumlah bulan atau hari lengkap, masing-masing.

Untuk mempelajari detailnya, saya mengundang Anda untuk mengunduh Kalkulator Zaman Excel ini dan menyelidiki rumus dalam sel B9: B11.

Unduh Kalkulator Usia untuk Excel

Kalkulator usia siap pakai untuk Excel


Mereka pengguna Ultimate Suite kami untuk Excel tidak perlu repot-repot membuat kalkulator usia sendiri di Excel - hanya dengan beberapa klik saja:

1. Pilih sel tempat Anda ingin menyisipkan rumus usia, buka tab Ablebits Tools > Grup Tanggal & Waktu , dan klik tombol Wizard Tanggal & Waktu .


2. Wizard Tanggal & Waktu akan dimulai, dan Anda langsung menuju ke tab Usia .
3. Pada tab Usia , ada 3 hal yang harus Anda tentukan:

  • Data kelahiran sebagai referensi sel atau tanggal dalam format hh / bb / tttt.
  • Umur pada tanggal hari ini atau tanggal tertentu .
  • Pilih apakah akan menghitung usia dalam hari, bulan, tahun, atau usia tepat.

4. Klik tombol Sisipkan rumus .
5. Selesai!


Formula dimasukkan dalam sel yang dipilih sebentar, dan Anda mengklik dua kali gagang isian untuk menyalinnya ke kolom.


Seperti yang mungkin telah Anda perhatikan, rumus yang dibuat oleh kalkulator usia Excel kami lebih kompleks daripada yang telah kami bahas sejauh ini, tetapi formula ini melayani satuan waktu tunggal dan jamak seperti "hari" dan "hari".

Jika Anda ingin menghilangkan nol unit seperti "0 hari", pilih kotak centang Jangan tampilkan nol unit :


Jika Anda ingin menguji kalkulator usia ini dan juga menemukan 60 tambahan add-in yang hemat waktu untuk Excel, Anda dapat mengunduh versi uji coba Ultimate Suite kami. Jika Anda menyukai alat dan memutuskan untuk mendapatkan lisensi, pastikan untuk mengambil kode kupon diskon 15% yang kami berikan kepada pembaca blog kami yang berharga: AB14-BlogSpo

Cara menyorot usia tertentu (di bawah atau di atas usia tertentu)


Dalam beberapa situasi, Anda mungkin perlu tidak hanya menghitung usia di Excel, tetapi juga menyorot sel yang mengandung usia di bawah atau di atas usia tertentu.

Jika rumus perhitungan usia Anda mengembalikan jumlah tahun lengkap, maka Anda dapat membuat aturan pemformatan bersyarat biasa berdasarkan rumus sederhana seperti ini:


  • Untuk menyorot usia yang sama dengan atau lebih besar dari 18: = $ C2> = 18
  • Untuk menyoroti usia di bawah 18: = $ C2 <18


Di mana C2 adalah sel paling atas di kolom Usia (tidak termasuk tajuk kolom).


Tetapi bagaimana jika formula Anda menampilkan usia dalam tahun dan bulan, atau dalam tahun, bulan dan hari? Dalam hal ini, Anda harus membuat aturan berdasarkan rumus DATEDIF yang menghitung usia sejak tanggal lahir tahun .

Misalkan tanggal lahir ada di kolom B dimulai dengan baris 2, rumusnya adalah sebagai berikut:


  • Untuk menyoroti usia di bawah 18 (kuning):

=DATEDIF($B2, TODAY(),"Y")<18


  • Untuk menyorot usia antara 18 dan 65 (hijau):

=AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)


  • Untuk menyoroti usia di atas 65 (biru):

=DATEDIF($B2, TODAY(),"Y")>65

Untuk membuat aturan berdasarkan rumus di atas, pilih sel atau seluruh baris yang ingin Anda sorot, buka tab Beranda > grup Gaya , dan klik Pemformatan Bersyarat > Aturan Baru ... > Gunakan rumus untuk menentukan sel mana yang akan diformat .


Ini adalah cara Anda menghitung usia di Excel. Saya harap formula ini mudah bagi Anda untuk dipelajari dan Anda akan mencobanya di lembar kerja Anda. Sampel Excel Age Perhitungan worksheet akan membuat sesuatu yang lebih mudah.

Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Comments

Popular posts from this blog

7 Cerita Pendek Tentang Kejujuran Paling Menginspirasi

Cara Hard Reset Oppo A9 2020 Bootloop Lupa Pola

Cara Hard Reset Oppo Reno 2 Bootloop Lupa Pola